AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TNotifyEvents

Ein Thema von Gyrospeter · begonnen am 14. Jan 2020 · letzter Beitrag vom 17. Jan 2020
Antwort Antwort
Seite 2 von 4     12 34   
Benutzerbild von Neutral General
Neutral General

Registriert seit: 16. Jan 2004
Ort: Bendorf
5.219 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#11

AW: TNotifyEvents

  Alt 14. Jan 2020, 11:20
Was einige Anfänger z.B. öfter mal fragen ist wie sie von ihrem Form2 einen Wert oder eine Komponente auf Form1 ändern können.
Eine der eleganteren Möglichkeiten ist ein Event in Form2 zu erstellen, für das Form1 einen Eventhandler schreibt.

Beispiel (Mehr oder weniger Pseudocode):

Angenommen ein Image auf Form1 soll angezeigt werden (Visible = true) wenn der Benutzer in Form2 auf einen Button klickt.
(Ist natürlich ein sehr künstliches Beispiel):

Unit2:
Delphi-Quellcode:
type
  TForm2 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    ...
  private
    FOnShowImageButtonClick: TNotifyEvent;
  public
    property OnShowImageButtonClick: TNotifyEvent read FOnShowImageButtonClick write FOnShowImageButtonClick;
  end;

implementation

procedure TForm2.Button1Click(Sender: TObject);
begin
  if Assigned(FOnShowImageButtonClick) then
    FOnShowImageButtonClick(Self);
end;
Unit1:
Delphi-Quellcode:
type
  TForm1 = class(TForm)
    Image1: TImage;
    procedure FormCreate(Sender: TObject);
    ..
  private
    procedure ShowImageButtonEventHandler(Sender: TObject);
  public
    { Public-Deklarationen }
  end;

implementation

procedure TForm1.ShowImageButtonEventHandler(Sender: TObject);
begin
  Image1.Visible := true;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2.OnShowImageButtonClick := ShowImageButtonEventHandler; // Form2 muss natürlich schon existieren
end;
Du kannst auch ein bisschen weiter gehen und deine eigenen Event-Typen definieren.
Angenommen du willst durch eine Aktion in Form2 eine Progressbar in Form1 steuern.

(Abgewandeltes Beispiel von oben):

Unit2:
Delphi-Quellcode:
type
  TMyProgressEvent = procedure(Sender: TObject; AProgressValue: Integer) of object; // of object bedeutet dass der Eventhandler eine Methode einer Klasse sein muss.
                                                                                    // ohne das wird als Eventhandler nur eine normale Proceure was normalerweise nicht gewünscht ist
  TForm2 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
    ...
  private
    FOnProgress: TMyProgressEvent;
  public
    property OnProgress: TMyProgressEvent read FOnProgress write FOnProgress;
  end;

implementation

procedure TForm2.Button1Click(Sender: TObject);
var i: Integer;
begin
  for i:= 0 to 100 do
  begin
    if Assigned(FOnProgress) then
      FOnProgress(Self, i);
    sleep(100); // Nur zum Testen ein bisschen Verzögerung/Arbeit simulieren
  end;
end;
Unit1:
Delphi-Quellcode:
type
  TForm1 = class(TForm)
    Progressbar1: TProgressbar;
    procedure FormCreate(Sender: TObject);
    ..
  private
    procedure ProgressEventHandler(Sender: TObject; AProgressValue: Integer);
  public
    { Public-Deklarationen }
  end;

implementation

procedure TForm1.ProgressEventHandler(Sender: TObject; AProgressValue: Integer);
begin
  Progressbar1.Position := AProgressValue;
  // Folgende Zeilen nur zur Demonstration. Ansonsten sollte man mit Application.ProcessMessages sparsam sein (Zeichnet u.a. die Progressbar neu)
  Application.ProcessMessages;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2.OnProgress := ProgressEventHandler; // Form2 muss natürlich schon existieren
end;
Anmerkung: Das sind jetzt natürlich blöde Beispiele. Man würde in den Fällen nicht zwangsweise für alles ein Event machen. Alternativ könnte man das Image bzw. die Progressbar auch (z.B. im Konstruktor) an Form2 übergeben und Form2 setzt die Werte dann direkt. Events sind vor allem in den Fällen interessant wo 1 oder mehrere Objekte (Form1, ...) auf eine Aktion eines anderen (Form2) reagieren müssen/wollen. Wenn Form3 z.B. auch Form2 aufrufen würde und dem OnProgressEvent ein Eventhandler zuweist der den aktuellen Fortschritt in einem Memo ausgibt, dann wäre ein Event gerechtfertigt weil es dann nicht mehr hilft Form2 im Konstruktor eine Progressbar zu übergeben, weil das Form3 nichts bringen würde.
Ich hoffe meine Erklärung ist nicht zu verwirrend
Michael
"Programmers talk about software development on weekends, vacations, and over meals not because they lack imagination,
but because their imagination reveals worlds that others cannot see."

Geändert von Neutral General (14. Jan 2020 um 11:29 Uhr)
  Mit Zitat antworten Zitat
Gyrospeter

Registriert seit: 11. Apr 2019
49 Beiträge
 
Delphi 10.4 Sydney
 
#12

AW: TNotifyEvents

  Alt 14. Jan 2020, 11:28
Das erste Beispiel habe ich verstanden und macht auch Sinn.

Warum sollte bzw. muss ich dann im zweiten Beispiel einen eigenen Event-Typen definieren? Wann macht sowas am meisten Sinn?

Vielen Dank schon mal und sorry für die dummen Fragen. Leider steige ich bei dem Thema Events sehr langsam hinterher...
  Mit Zitat antworten Zitat
Benutzerbild von Neutral General
Neutral General

Registriert seit: 16. Jan 2004
Ort: Bendorf
5.219 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#13

AW: TNotifyEvents

  Alt 14. Jan 2020, 11:32
Weil ein TNotifyEvent folgendermaßen definiert ist:
Delphi-Quellcode:
type
  TNotifyEvent = procedure(Sender: TObject) of object;
Das bedeutet einem TNotifyEvent kann man (bis auf den Sender) keine weiteren Werte übergeben.
Wenn du dem Handler des Events zusätzliche Daten zur Verfügung stellen willst (wie z.B. den ProgressValue im 2. Beispiel) musst du einen eigenen Typ definieren mit den Parametern die du zusätzlich übergeben willst:
Delphi-Quellcode:
type
  TMyProgressEvent = procedure(Sender: TObject; AProgressValue: Integer) of object; // Wir wollen AProgressValue zusätzlich mitgeben. Also brauchen wir einen eigenen Typen, weil TNotifyEvent das nicht unterstützt.
Michael
"Programmers talk about software development on weekends, vacations, and over meals not because they lack imagination,
but because their imagination reveals worlds that others cannot see."
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#14

AW: TNotifyEvents

  Alt 14. Jan 2020, 11:50
Zuerst mal würde ich mich von dem Schlagwort TNotifyEvent verabschieden. Das führt hier in die Irre. Du suchst nach einem Tutorial über Eventhandler. TNotifyEvent ist ein Eventhandler unter vielen. Oder genauer gesagt die Deklaration eines Eventhandler-Typen. Ich weiß, noch mehr Fragezeichen

Ein recht gutes Tutorial kommt von Embarcadero selbst.

Und um deine andere Frage zu beantworten: Die große Mehrheit der Eventhandler sind Prozeduren. Allerdings können technisch gesehen genauso gut auch Funktionen verwendet werden.

Warum sollte bzw. muss ich dann im zweiten Beispiel einen eigenen Event-Typen definieren? Wann macht sowas am meisten Sinn?
Außer zu Lernzwecken? Grundsätzlich solltest du immer erst schauen ob es für deinen jeweiligen Bedarf nicht schon passende Eventhandlertypen gibt.

Eventhandler sind nützlich, wenn du eine Klasse schreibst und diese in einer separaten Unit liegt. Wenn deine Klasse eine Prozedur in deinem Hauptprogramm aufrufen soll, muss sie ja wissen welche und muss sie auch erreichen können. In schlecht programmierten Codes entstehen bei sowas Kreuzbezüge bzw. zirkuläre Referenzen. Das heißt, die Unit1 bindet Unit2 ein und Unit2 bindet Unit1 ein. Die haben mich schon viele graue Haare gekostet.

Guter Code lagert Klassen in separate Units aus und weist keine zirkulären Referenzen auf. Um das zu erreichen, sind Eventhandler ein guter Weg.
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden

Geändert von Codehunter (14. Jan 2020 um 11:58 Uhr)
  Mit Zitat antworten Zitat
Gyrospeter

Registriert seit: 11. Apr 2019
49 Beiträge
 
Delphi 10.4 Sydney
 
#15

AW: TNotifyEvents

  Alt 14. Jan 2020, 11:57
Warum funktioniert das zb. nicht?

Code:
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);

  private
    { Private-Deklarationen }
    FOnEvent: TNotifyEvent;
  public
    { Public-Deklarationen }
    property OnEvent: TNotifyEvent read FOnEvent write FOnEvent;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}


{ TForm1 }

procedure TForm1.Button1Click(Sender: TObject);
begin
  Memo1.Lines.Add ('Button 1 pressed');

  if Assigned(FOnEvent) then
    FOnEvent(Self);
end;


procedure TForm1.Button2Click(Sender: TObject);
begin
  Memo1.Lines.Add ('Button 2 pressed');
end;


procedure TForm1.Button3Click(Sender: TObject);
begin
  if Assigned(FOnEvent) then
  begin
    Memo1.Lines.Add ('Nothing assigned');
    FOnEvent := nil;
  end
  else
    FOnEvent := Button2Click;
end;

end.

Zitat:
Zuerst mal würde ich mich von dem Schlagwort TNotifyEvent verabschieden. Das führt hier in die Irre. Du suchst nach einem Tutorial über Eventhandler. TNotifyEvent ist ein Eventhandler unter vielen. Oder genauer gesagt die Deklaration eines Eventhandler-Typen. Ich weiß, noch mehr Fragezeichen

Ein recht gutes Tutorial kommt von Embarcadero selbst.

Und um deine andere Frage zu beantworten: Die große Mehrheit der Eventhandler sind Prozeduren. Allerdings können technisch gesehen genauso gut auch Funktionen verwendet werden.
Danke, lese ich mir mal durch.
  Mit Zitat antworten Zitat
Gyrospeter

Registriert seit: 11. Apr 2019
49 Beiträge
 
Delphi 10.4 Sydney
 
#16

AW: TNotifyEvents

  Alt 14. Jan 2020, 12:08
Außer zu Lernzwecken? Grundsätzlich solltest du immer erst schauen ob es für deinen jeweiligen Bedarf nicht schon passende Eventhandlertypen gibt.

Eventhandler sind nützlich, wenn du eine Klasse schreibst und diese in einer separaten Unit liegt. Wenn deine Klasse eine Prozedur in deinem Hauptprogramm aufrufen soll, muss sie ja wissen welche und muss sie auch erreichen können. In schlecht programmierten Codes entstehen bei sowas Kreuzbezüge bzw. zirkuläre Referenzen. Das heißt, die Unit1 bindet Unit2 ein und Unit2 bindet Unit1 ein. Die haben mich schon viele graue Haare gekostet.

Guter Code lagert Klassen in separate Units aus und weist keine zirkulären Referenzen auf. Um das zu erreichen, sind Eventhandler ein guter Weg.
Aber dafür hab ich doch die Public properties in den Units und kann dann dort auf die Methoden zugreifen oder nicht?
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#17

AW: TNotifyEvents

  Alt 14. Jan 2020, 12:13
Aber dafür hab ich doch die Public properties in den Units und kann dann dort auf die Methoden zugreifen oder nicht?
Kurze Antwort: Ja. Lange Antwort: Machs nicht.
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden

Geändert von Codehunter (14. Jan 2020 um 12:21 Uhr)
  Mit Zitat antworten Zitat
Gyrospeter

Registriert seit: 11. Apr 2019
49 Beiträge
 
Delphi 10.4 Sydney
 
#18

AW: TNotifyEvents

  Alt 14. Jan 2020, 12:19
Kurze Antwort: Ja. Lange Antwort: Machs nicht.
Ok

Delphi-Quellcode:
procedure TForm1.Button3Click(Sender: TObject);
begin
  //if Assigned(FOnEvent) then // FALSCH HERUM!
  if not Assigned(FOnEvent) then
  begin
    Memo1.Lines.Add ('Nothing assigned');
    FOnEvent := nil;
  end
  else
    FOnEvent := Button2Click;
end;
Funktioniert leider nicht. Denn ich will ja Button2 ausgeben wenn es Assigned ist. Im Optimalfall natürlich Button 1 und 2...
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
2.272 Beiträge
 
Delphi 10.4 Sydney
 
#19

AW: TNotifyEvents

  Alt 14. Jan 2020, 12:29
Funktioniert leider nicht. Denn ich will ja Button2 ausgeben wenn es Assigned ist. Im Optimalfall natürlich Button 1 und 2...
Ja deswegen hab ich das oben wieder rausgenommen. Ich hatte den Gedankengang nicht verstanden. Dein Code ist verwirrend weil du versuchst innerhalb der selben Klasse (TForm1) mit den Eventhandlern dieser Klasse zu hantieren. Also quasi sich selbst an den Haaren aus dem Sumpf ziehen
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.679 Beiträge
 
Delphi 2007 Enterprise
 
#20

AW: TNotifyEvents

  Alt 14. Jan 2020, 12:56
Sieh Event-Handler als Verweis auf eine Prozedur, und Event-Typen als Beschreibung, welche Parameter diese Prozedur haben muss.

Die Grundidee ist, dass du eine Prozedur aufrufen kannst, ohne zu wissen wie diese heißt und wo sie her kommt. Für dich ist nur wichtig, welche Parameter hinein gehen. Was nachher genau aufgerufen wird, bestimmt ein anderer Teil des Programmes, an dem einem Handler eine konkrete echte Prozedur zugewiesen wird.

Delphi-Quellcode:
type
  TMyEvent = procedure(Wert1: Integer; Wert2: String) of object;

  TMyClass = class
  private
    FOnMyEvent: TMyEvent;
    procedure DoSomething;
  public
    property OnMyEvent read FOnMyEvent write FOnMyEvent;
  end;

implementation

procedure TMyClass.DoSomething;
begin
  // mache irgendwas, wobei etwas passiert was MyEvent auslösen soll
  if Assigned(FOnMyEvent) then
    FOnMyEvent(123, 'Foo');
end;
Delphi-Quellcode:
type
  TForm1 = class(TForm)
  private
    MyObject: TMyClass;
    procedure MyEventHandler(Wert1: Integer; Wert2: String);
  end;

implementation

procedure TForm1.OnCreate(Sender: TObject);
begin
  MyObject := TMyClass.Create;
  MyObject.OnMyEvent := MyEventHandler; // <-- ab jetzt ist der Aufruf von FOnMyEvent() oben in TMyClass identisch mit einem Aufruf von MyEventHandler() in TForm1
end;

procedure TForm1.MyEventHandler(Wert1: Integer; Wert2: String);
begin
  ShowMessage('Es ist etwas passiert! Und zwar: '+IntToStr(Wert1)+' und '+Wert2); // Ausgabe wenn TMyClass.OnMyEvent() wie oben aufgerufen wird: "Es ist etwas passiert! Und zwar: 123 und Foo"
end;

Der große Vorteil ist, dass TMyClass hierdurch Prozeduren aus anderen Klassen aufrufen kann, ohne die Klasse, deren Herkunft oder sonst irgend etwas zu wissen. Man kann einfach dynamisch irgend eine Prozedur zuweisen - sie muss nur dieselben Parameter haben. Und das stellt man am besten sicher, indem man einen Typ "procedure() of object" nimmt, der diese sog. Signatur typsicher festlegt. TNotifyEvent ist lediglich solch ein Typ, und besagt "irgend eine Prozedur (die einem Objekt zugeordnet ist), die einen Parameter vom Typ TObject hat". Mehr nicht.

Das ganze MUSS nichtmals nur für Events genutzt werden. Das Konzept ist generell verwendbar, bietet sich aber für Events sehr an. (Genau genommen sind "Events" auch nur eine lose Definition, kein eigenständiges Konzept der Sprache an sich. Es sind einfach Methodenzeiger, die aufgerufen werden, wenn dies semantisch als ein Ereignis interpretiert werden kann. Man kann Methodenzeiger auch anders einsetzen. Hier wird's aber etwas philosophischer )
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)

Geändert von Medium (14. Jan 2020 um 13:01 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 09:36 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz